Air pollution is one of the largest environmental and public health challenges in the world today. It leads to adverse effects on our health, climate, and ecosystem. Monitoring air quality is essential to understanding and preventing air pollution, as well as assessing emission sources, in order to preserve healthier air conditions and contribute to the fight against the greenhouse effect.

This project creates two devices that communicate with each other via LoRa wireless communication. There are many sensors that can be used to monitor air quality, but this project focuses on two: the DSM501A dust sensor and the MQ131 ozone gas sensor. These sensors are connected to the first device, which uses the Ra-02 LoRa module as the client transceiver. The second device uses a LoRa shield as the server transceiver and a SIM800L as the gateway connection to ThingSpeak.

This project suits makers, students, or environmental monitoring enthusiasts who want to build a long-range, cellular-connected air quality station — placing sensors somewhere remote (no Wi-Fi needed) and viewing the readings on a ThingSpeak dashboard from anywhere.

Gather everything below before you start.

The Ra-02 LoRa module can be used for ultra-long distance spread spectrum communication, with compatible FSK (frequency shift keying) remote modulation and demodulation. This provides a solution for traditional wireless designs that have poor distance coverage, anti-interference, and power consumption. The Ra-02 can be widely used in networking scenarios such as automatic meter reading, home/building automation, security systems, and remote irrigation systems.

Specifications

The Dragino LoRa Shield is a long-range transceiver in an Arduino shield form factor, based on an open-source library. It allows the user to send data and reach extremely long ranges at low data rates, providing ultra-long range spread spectrum communication and high interference immunity while minimizing current consumption.

Specifications

How Do They Work?

The SIM800L is a cellular module that allows for GPRS data transmission, sending and receiving SMS, and making and receiving voice calls. The board is compact and has low current consumption, with a power-saving technique that limits current draw to as low as 1 mA when idle. It supports quad-band GSM/GPRS network, meaning it works in most places around the world.

How Does It Work?

The DSM501A dust sensor module is a low-cost, compact particle density sensor capable of quantitative particle measurement of fine particles as small as one micron.

How Does It Work?

The MQ131 Ozone Gas Sensor, as its name suggests, senses ozone gas (O3). It has high sensitivity to ozone while also being sensitive to strong oxides such as Cl2 and NO2. It's widely used in air quality monitoring applications, whether domestic or industrial.

How Does It Work?

Ra-02 LoRa Module Connections

DSM501A Dust Sensor Connections

MQ131 Ozone Gas Sensor Connections

The Dragino LoRa Shield plugs directly onto the second Arduino Uno as a shield — no manual pin wiring is required for the LoRa radio itself. The SIM800L module then connects to this Arduino for cellular connectivity.

Follow these steps to set up your ThingSpeak channel before uploading the server code.

Sign up at thingspeak.com. If you already have an account, log in and click "Channels", then click "New Channel" to create one.

Fill in the required Channel Settings and check 2 fields — one for each sensor reading (dust and ozone). You only need to give it a name and a description; the rest are unnecessary. When done, scroll to the bottom and click "Save Channel".

You can view your channel privately by clicking the "Private View" tab at the top, and customize each field's chart by clicking its pencil icon.

You'll need your channel's write API key for the Arduino code so the SIM800L can transmit data to ThingSpeak. Find it under the "API Keys" tab at the top of your channel page.

Read the Code Breakdown section to understand what each part does.

Pre-Initialization

#include <RHReliableDatagram.h>
#include <RH_RF95.h>
#include <SPI.h>
#include "DSM501.h"
#include "MQ131.h"

#define CLIENT_ADDRESS 123
#define SERVER_ADDRESS 321

RH_RF95 driver;
RHReliableDatagram manager(driver, CLIENT_ADDRESS);

int dustSensorPin = 7; //PM2.5
int o3sensorPin = A0;
DSM501 dsm501(6, dustSensorPin);
MQ131 o3sensor(4, o3sensorPin, LOW_CONCENTRATION, 10000);
char buf[RH_RF95_MAX_MESSAGE_LEN];

setup()

Serial.begin(9600);
if (!manager.init())
  Serial.println("init failed");
dsm501.begin(MIN_WIN_SPAN);
o3sensor.setR0(252564.10); //set base resistance R0 value
o3sensor.setTimeToRead(30); //set time to read value 30s

loop() — Dust Sensor Reading

dsm501.update();
Serial.print("Dust Concentration: ");
Serial.print(dsm501.getParticleWeight(1));
Serial.println(" µg/m3");

char data1[8];
dtostrf(dsm501.getParticleWeight(1), 5, 2, data1);

if (manager.sendtoWait(data1, sizeof(data1), SERVER_ADDRESS)) {
  uint8_t len = sizeof(buf);
  uint8_t from;   
  if (manager.recvfromAckTimeout(buf, &len, &from)) {
    Serial.print("reply from 0x");
    Serial.print(from, HEX);
    Serial.print(": ");
    Serial.println(buf);
  }
  else {
    Serial.println("No reply");
  }
}
else {
  Serial.println("sendtoWait failed"); 
}
delay(500);

loop() — Ozone Sensor Reading

o3sensor.begin();
Serial.print("Ozone Gas: ");
Serial.print(o3sensor.getO3(UG_M3));
Serial.println(" µg/m3\t");

char data2[8];
dtostrf(o3sensor.getO3(UG_M3), 4, 2, data2);

Pre-Initialization

#include <RHReliableDatagram.h>
#include <RH_RF95.h>
#include <SPI.h>
#include <SoftwareSerial.h>

SoftwareSerial gsm(2, 3); // RX, TX of Arduino

#define CLIENT_ADDRESS 123
#define SERVER_ADDRESS 321

RH_RF95 driver;
RHReliableDatagram manager(driver, SERVER_ADDRESS);

char data[] = "Message Received";
char buf[RH_RF95_MAX_MESSAGE_LEN];
uint8_t index = 1; //1 for first data, 2 for 2nd

setup()

Serial.begin(9600);
gsm.begin(4800); // Set GSM Baudrate
if (!manager.init())
  Serial.println("init failed");

SIM800L AT Commands for Sending Data to ThingSpeak

void gsmSend() {
  String updateTS = "GET https://api.thingspeak.com/update?api_key=4Z6XNGVB0ZEGKNFJ&field";
  String updateTSvalue = updateTS + index + "=" + atof(buf);
  gsm.println("AT+CIPMODE=0");
  delay(2000);
  gsm.println("AT+CIPMUX=0");
  delay(2000);
  gsm.println("AT+CGATT=1");
  delay(2000);
  gsm.println("AT+CSTT=\"http.globe.com.ph\"");
  delay(2000);
  gsm.println("AT+CIICR");
  delay(2000);
  gsm.println("AT+CIFSR");
  delay(2000);
  gsm.println("AT+CIPSTART=\"TCP\",\"184.106.153.149\",\"80\"");
  delay(2000);
  gsm.println("AT+CIPSEND=80");
  delay(2000);
  gsm.println(updateTSvalue);
  delay(2000);
  gsm.println("AT+CIPSHUT");
}

loop()

if (manager.available()) {
  if (index == 1) {
    uint8_t len = sizeof(buf);
    uint8_t from;
    if (manager.recvfromAck(buf, &len, &from))
    {
      Serial.println(buf);
      if (!manager.sendtoWait(data, sizeof(data), from))
        Serial.println("sendtoWait failed");
    }
    gsmSend();
    index = 2;
  }
  else if (index == 2) {
    uint8_t len = sizeof(buf);
    uint8_t from;
    if (manager.recvfromAck(buf, &len, &from))
    {
      Serial.println(buf);
      if (!manager.sendtoWait(data, sizeof(data), from))
        Serial.println("sendtoWait failed");
    }
    gsmSend();
    index = 1;
  }
}

LoRa is a low data rate, low power wireless platform technology for building IoT networks. It's more cost-efficient in the long run compared to other alternatives due to its wide feature set — its transceivers can communicate up to 15 kilometers apart, which is more than enough for many applications. LoRa Technology operates in the unlicensed ISM band, making it legal and well-suited for educational purposes.

The sensors used for this project were a bit harder to test due to the difficulty of finding comparison values — you have to be fairly specific when searching online for air quality monitoring standards for dust particulate matter and ozone gas concentration. Fortunately, the libraries used for both sensors handle the underlying calculations.

These are the guidelines/standards defined by the World Health Organization for dust particulate matter (PM2.5) and ground-level ozone gas. To get the AQI (Air Quality Index) for comparison, you can use an online AQI calculator. See the WHO guideline document in References for the specific threshold values.

• MQ131 Low Concentration Datasheet — GitHub (ostaquet/Arduino-MQ131-driver)
  (https://github.com/ostaquet/Arduino-MQ131-driver/blob/master/datasheet/MQ131-low-concentration.pdf)
• SIM900 AT Command Manual — SIMCom
  (https://simcom.ee/documents/SIM900/SIM900_AT%20Command%20Manual_V1.11.pdf)
• Spread Spectrum Communications — ScienceDirect
  (https://www.sciencedirect.com/topics/engineering/spread-spectrum-communications)
• WHO Air Quality Guidelines — World Health Organization
  (https://apps.who.int/iris/bitstream/handle/10665/69477/WHO_SDE_PHE_OEH_06.02_eng.pdf?sequence=1)

• Johnson Hong

• Lukie-Mar Lonzaga
• Miles Darren Bagnol
• Elijah Joseph Orias